{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    nixpkgs-small.url = "github:NixOS/nixpkgs/nixos-unstable-small";
    nextcloud = {
      url = "github:onny/nixos-nextcloud-testumgebung";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    gtrackmap = {
      url = "github:gtrackmap/gtrackmap/ef27a0397c4d73dc31e7b49c8a2736ae62b5a3ff";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    lanzaboote.url = "github:nix-community/lanzaboote";
    nixos-hardware.url = "github:NixOS/nixos-hardware/master";
    auto-cpufreq = {
      url = "github:AdnanHodzic/auto-cpufreq";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    home-manager = {
      url = "github:nix-community/home-manager";
      inputs = {
        nixpkgs.follows = "nixpkgs";
      };
    };
    commander-nvim = {
      url = "github:FeiyouG/commander.nvim";
      flake = false;
    };
    vimpeccable = {
      url = "github:svermeulen/vimpeccable";
      flake = false;
    };
    windline-nvim = {
      url = "github:windwp/windline.nvim";
      flake = false;
    };
    gen-nvim = {
      url = "github:David-Kunz/gen.nvim";
      flake = false;
    };
    ketchup = {
      url = "github:repomaa/ketchup";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    ksoloti-pr.url = "github:repomaa/nixpkgs/pkg/ksoloti";
  };
  outputs = { nixpkgs, nixpkgs-small, gtrackmap, ksoloti-pr, lanzaboote, nixos-hardware, auto-cpufreq, home-manager, ... }@inputs: {
    nixosConfigurations.freun-dev = nixpkgs.lib.nixosSystem {
      system = "x86_64-linux";
      specialArgs = inputs;
      modules = [
        ./freun.dev
        gtrackmap.nixosModules.x86_64-linux.default
      ];
    };

    nixosConfigurations.radish = nixpkgs.lib.nixosSystem rec {
      system = "x86_64-linux";
      specialArgs = {
        pkgs-small = import nixpkgs-small { inherit system; };
        ksoloti-pr = import ksoloti-pr { inherit system; };
        inherit inputs system;
      };
      modules = [
        ./radish
        lanzaboote.nixosModules.lanzaboote
        nixos-hardware.nixosModules.framework-13-7040-amd
        auto-cpufreq.nixosModules.default
        home-manager.nixosModules.home-manager
      ];
    };
  };
}