{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    nixpkgs-small.url = "github:NixOS/nixpkgs/nixos-unstable-small";
    nextcloud = {
      url = "github:onny/nixos-nextcloud-testumgebung";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    gtrackmap = {
      url = "github:gtrackmap/gtrackmap";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    lanzaboote.url = "github:nix-community/lanzaboote";
    nixos-hardware.url = "github:NixOS/nixos-hardware/master";
    ksoloti-pr.url = "github:repomaa/nixpkgs/pkg/ksoloti";
    auto-cpufreq = {
      url = "github:AdnanHodzic/auto-cpufreq";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };
  outputs = { nixpkgs, nixpkgs-small, gtrackmap, ksoloti-pr, lanzaboote, nixos-hardware, auto-cpufreq, ... }@attrs: {
    nixosConfigurations.freun-dev = nixpkgs.lib.nixosSystem {
      system = "x86_64-linux";
      specialArgs = attrs;
      modules = [
        ./freun.dev
        gtrackmap.nixosModules.x86_64-linux.default
      ];
    };

    nixosConfigurations.radish = nixpkgs.lib.nixosSystem rec {
      system = "x86_64-linux";
      specialArgs = {
        pkgs-small = import nixpkgs-small { inherit system; };
        ksoloti-pr = import ksoloti-pr { inherit system; };
        inherit attrs system;
      };
      modules = [
        ./radish
        lanzaboote.nixosModules.lanzaboote
        nixos-hardware.nixosModules.framework-13-7040-amd
        auto-cpufreq.nixosModules.default
      ];
    };
  };
}